Comments change compiled behavior (sysTickHook weak reference override)

Question

I have a very simple routine that lights up the built-in LED (pin 13) when a system tick timer fires off its interrupt.

I override the weak reference to int sysTickHook(void) found in hooks.c. I found that in generalfor this to work I need to use extern "C" linkage

The part that is bewildering is that this interrupt fires off fine without extern "C" if there are the comments above it as shown below. This is the minimal reproducible example I can find. Can someone explain this?

I'm using the plain old Arduino IDE 1.8.16.

void setup() {
  pinMode(13,OUTPUT);  
  digitalWrite(13,LOW);
}

void loop() {}

// {          -- if you remove this line sysTickHook will not be called
// extern "C" -- if you remove this line sysTickHook will not be called
int sysTickHook()
{        
  digitalWrite(13,HIGH);
  return 0;
}

Answer 1

The problem is the preprocessor in the IDE. It's not clever enough to work out the extern "C" when adding function prototypes.

With your comments you end up with:

#include <Arduino.h>
#line 1 "/home/matt/t/t.ino"
#line 1 "/home/matt/t/t.ino"
void setup();
#line 6 "/home/matt/t/t.ino"
void loop();
#line 10 "/home/matt/t/t.ino"
 extern "C" int sysTickHook(); // << The extern gets added here from the comment
#line 1 "/home/matt/t/t.ino"
void setup() {
  pinMode(13,OUTPUT);  
  digitalWrite(13,LOW);
}

void loop() {}

// {          -- if you remove this line sysTickHook will not be called
// extern "C" -- if you remove this line sysTickHook will not be called
int sysTickHook()
{        
  digitalWrite(13,HIGH);
  return 0;
}

It finds the extern in the comment and thinks it's real code. If you remove the comment markers it ends up with broken code, as you have a stray { in there. If you remove the comments entirely you end up with the function in the C++ linkage, which changes the function name internally and doesn't then override the weak function. The same happens if you remove just the first comment.

Basically having those comments breaks the preprocessor in such a way that it works. The proper way of doing it is:

void setup() {
  pinMode(13,OUTPUT);  
  digitalWrite(13,LOW);
}

void loop() {}

extern "C" {
  int sysTickHook()
  {        
    digitalWrite(13,HIGH);
    return 0;
  }
}