0

I'm using millis () function to control the timer of my LED. It is a very basic code that I used from the example libraries. The code worked well for 6 hours (On for 6 h, Off for the following 6 h and continues), however, when I set it up for 12 hours, the light failed to turn off when I checked on it. The designed time should have fit into the 2^32 bits for unsigned long which I have defined beforehand. Can someone please help on this issue? Thank you!

/*
  Blink without Delay

  Turns on and off a light emitting diode (LED) connected to a digital pin,
  without using the delay() function. This means that other code can run at the
  same time without being interrupted by the LED code.

  The circuit:
  - Use the onboard LED.
  - Note: Most Arduinos have an on-board LED you can control. On the UNO, MEGA
    and ZERO it is attached to digital pin 13, on MKR1000 on pin 6. LED_BUILTIN
    is set to the correct LED pin independent of which board is used.
    If you want to know what pin the on-board LED is connected to on your
    Arduino model, check the Technical Specs of your board at:
    https://www.arduino.cc/en/Main/Products

  created 2005
  by David A. Mellis
  modified 8 Feb 2010
  by Paul Stoffregen
  modified 11 Nov 2013
  by Scott Fitzgerald
  modified 9 Jan 2017
  by Arturo Guadalupi

  This example code is in the public domain.

  http://www.arduino.cc/en/Tutorial/BlinkWithoutDelay
*/

// constants won't change. Used here to set a pin number:
const int ledPin =  7;// the number of the LED pin

// Variables will change:
int ledState = LOW;             // ledState used to set the LED

// Generally, you should use "unsigned long" for variables that hold time
// The value will quickly become too large for an int to store
unsigned long previousMillis = 0;        // will store last time LED was updated

// constants won't change:
unsigned long interval = 12*60*60*1000UL;           // interval at which to blink (milliseconds)

void setup() {
  // set the digital pin as output:
  pinMode(ledPin, OUTPUT);
}

void loop() {
  // here is where you'd put code that needs to be running all the time.

  // check to see if it's time to blink the LED; that is, if the difference
  // between the current time and last time you blinked the LED is bigger than
  // the interval at which you want to blink the LED.
  unsigned long currentMillis = millis();

  if (currentMillis - previousMillis >= interval) {
    // save the last time you blinked the LED
    previousMillis = currentMillis;

    // if the LED is off turn it on and vice-versa:
    if (ledState == LOW) {
      ledState = HIGH;
    } else {
      ledState = LOW;
    }

    // set the LED with the ledState of the variable:
    digitalWrite(ledPin, ledState);
  }
}
  • please look at your post ... does the program listing look the way you intended it to look? ... please format your code ... use the {} button – jsotola Mar 4 at 5:15
  • use unsigned long interval = 1000UL*12*60*60*; – Juraj Mar 4 at 5:37
1

In C++, the multiplication operator is “left-associative”. This means that the expression

12*60*60*1000UL

is interpreted as

((12*60)*60)*1000UL

The left factor, namely (12*60)*60, is computed using the int data type, but the result overflows that format, resulting in the problem you see.

The simple solution is to make one of the factors of the first product be an unsigned long. For example

1000UL*60*60*12

Then, 1000UL*60 is computed with the unsigned long data type. Since the result is itself an unsigned long, the next multiplication is also done as unsigned long, and likewise for the last one.

If you find this technique somewhat obscure, you can also add the UL suffix to every single factor. This would avoid implicit conversions by the compiler, making all the types explicit.

| improve this answer | |
  • The problem is panned out! Thank you sir! Programming is not my field at all and so I am clearly with no base. Your comment is very helpful and much appreciated. – syuen Mar 9 at 6:42
0

Did you try to change your variables so that the calculations would be in seconds instead of milliseconds ? IOW add "/1000" after millis() and reduce your constants accordingly.

millis() is overflowing periodically, but it only happens every 49 days or so, and that even shouldn't play a role in the way you use it (the difference will also kind of overflow in the other direction).

| improve this answer | |
  • Do not add /1000 after millis(), otherwise you will have a problem when millis() rolls over. – Edgar Bonet Mar 4 at 8:23

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.