0

I am trying to send and receive data using I2C between an Arduino Nano and an ATTiny85. The ATTiny is mounted on this board: Link

I've tried to reach the slave with the simple I2C scanner, but I don't find anything.

Those are the codes:

Master (I2C scanner):

// --------------------------------------
// i2c_scanner
//
// Version 1
//    This program (or code that looks like it)
//    can be found in many places.
//    For example on the Arduino.cc forum.
//    The original author is not know.
// Version 2, Juni 2012, Using Arduino 1.0.1
//     Adapted to be as simple as possible by Arduino.cc user Krodal
// Version 3, Feb 26  2013
//    V3 by louarnold
// Version 4, March 3, 2013, Using Arduino 1.0.3
//    by Arduino.cc user Krodal.
//    Changes by louarnold removed.
//    Scanning addresses changed from 0...127 to 1...119,
//    according to the i2c scanner by Nick Gammon
//    http://www.gammon.com.au/forum/?id=10896
// Version 5, March 28, 2013
//    As version 4, but address scans now to 127.
//    A sensor seems to use address 120.
// Version 6, November 27, 2015.
//    Added waiting for the Leonardo serial communication.
//
//
// This sketch tests the standard 7-bit addresses
// Devices with higher bit address might not be seen properly.
//

#include <Wire.h>


void setup()
{
  Wire.begin();

  Serial.begin(9600);
  while (!Serial);             // Leonardo: wait for serial monitor
  Serial.println("\nI2C Scanner");
}


void loop()
{
  byte error, address;
  int nDevices;

  Serial.println("Scanning...");

  nDevices = 0;
  for(address = 1; address < 127; address++ )
  {
    // The i2c_scanner uses the return value of
    // the Write.endTransmisstion to see if
    // a device did acknowledge to the address.
    Wire.beginTransmission(address);
    error = Wire.endTransmission();

    if (error == 0)
    {
      Serial.print("I2C device found at address 0x");
      if (address<16)
        Serial.print("0");
      Serial.print(address,HEX);
      Serial.println("  !");

      nDevices++;
    }
    else if (error==4)
    {
      Serial.print("Unknown error at address 0x");
      if (address<16)
        Serial.print("0");
      Serial.println(address,HEX);
    }    
  }
  if (nDevices == 0)
    Serial.println("No I2C devices found\n");
  else
    Serial.println("done\n");

  delay(500);           // wait 5 seconds for next scan
}

And this is the code of the ATTiny85 (slave):

#include <TinyWire.h>

#define led_pin 1

byte own_address = 10;


void setup() {
  // config led_pin as Output for driving an LED
  pinMode(led_pin, OUTPUT);

  // config TinyWire library for I2C slave functionality
  TinyWire.begin( own_address );
  // sets callback for the event of a slave receive
  TinyWire.onReceive( onI2CReceive );
}

void loop() {

}

/*
I2C Slave Receive Callback:
Note that this function is called from an interrupt routine and shouldn't take long to execute
*/
void onI2CReceive(int howMany){
  // loops, until all received bytes are read
  while(TinyWire.available()>0){
    // toggles the led everytime, when an 'a' is received
    if(TinyWire.read()=='a') digitalWrite(led_pin, !digitalRead(led_pin));
  }
}

Once I've programmedo both the boards I've connected SCL and SCK pins of the boards together.

If i open the serial monitor of the master this is what i get:

I2C Scanner Scanning... Unknown error at address 0x20 Unknown error at address 0x21 No I2C devices found

Scanning... Unknown error at address 0x78 No I2C devices found

Scanning... No I2C devices found

Scanning... Unknown error at address 0x08 Unknown error at address 0x09 Unknown error at address 0x60 No I2C devices found

Scanning... Unknown error at address 0x70 No I2C devices found

And so on. Can someone explain me were I'm doing errors?

  • did you wire ground together? – Juraj Feb 26 at 10:29
  • @Juraj you're right, i've forgot to wire them to the same ground. But now i only read "No I2C devices found" – Banfotech _ Feb 26 at 10:42
1

Problem solved!

I've modified the code, this is the final one:

#include <TinyWire.h>

#define led_pin 1
#define I2C_SLAVE_ADDR  0x11  


void setup() {
    // config led_pin as Output for driving an LED
    pinMode(led_pin, OUTPUT);

    // config TinyWire library for I2C slave functionality
    TinyWire.begin( I2C_SLAVE_ADDR );
    // sets callback for the event of a slave receive
    TinyWire.onReceive( onI2CReceive );
}

void loop() {

}

/*
I2C Slave Receive Callback:
Note that this function is called from an interrupt routine and shouldn't take long to execute
*/
void onI2CReceive(int howMany){
    // loops, until all received bytes are read
    while(TinyWire.available()>0){
        // toggles the led everytime, when an 'a' is received
        if(TinyWire.read()=='a') digitalWrite(led_pin, !digitalRead(led_pin));
    }
}

Like this the I2C scanner sees the board at the address 0x11.

The wirings are the following:

  • Arduino pin SCL to ATTiny85 pin SCL (P2)
  • Arduino pin SDA to ATTiny85 pinSDA (P0)
  • Take care of wire to the same ground both the boards.
  • The I2C address is 7 bits long, followed by the direction bit. So 10 or 11 are the same address but the direction bit is different. 0x10 is reserved address. i2c-bus.org/addressing – Juraj Feb 26 at 12:08
  • @Juraj Your are right in the address being 7 bits long. But the address for the TinyWire library (and also the Wire library) does not include the direction bit. It is added to the address byte by the library depending on the used functions. So 10 and 11 are not the same address here. – chrisl Feb 27 at 6:32
  • @chrisl, yes. decimal 10 is very different from 0x11 – Juraj Feb 27 at 7:57
  • Also 0x11 and 0x10 are not the same address, since this does not include the direction bit – chrisl Feb 27 at 18:00
  • @chrisl, how would you set the direction bit on 0x10 and 0x11 to be different addresses? – Juraj Feb 28 at 6:03

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.