Is it possible to insert your own routine into the Reset procedure

Question

I'm working with ATmega328 NANO boards, and I would like to know if it is possible to INSERT my own routine, to be included in the things done during reset, BEFORE any pre-C initialization is done, or any upload of new code occurs. If this is possible, I'd like to know how. I'd want to be able to "install" this routine during setup(). I also would not expect it to work after a power loss. I'm talking about a reset caused by pressing the reset button, uploading code, opening a serial port, or any reset that was NOT caused by a loss of power.

I'm including a simple example sketch illustrating what I would LIKE to do, but it obviously won't do what I want as written, because I do not know the "magic" answer I'm seeking,

I've defined and initialized a global static byte outside of any functions. The setup() simply reads a byte from EEPROM and displays it with Serial.print(), and then stores its value in that global 'number'. Now notice I created a void(void) function called magic(). It simply increments the global number and stores it in EEPROM. I call it "magic() because what I need to do to call it is unknown. I want some way to "install" magic() during setup(), so that it runs only as part of the reset process, before anything within code or data space is affected. By install, I don't mean just call the function. It should not actually be called unless RESET occurs. Whatever "magic" has to be added to make this happen, the proof of the pudding will be that after loading the sketch. every time you press RESET, or even upload the sketch again, the printed number will be different, because it was incremented and saved when reset was pushed. NOTE: (I just edited some stupid errors here)

#include <EEPROM.h>

static uint8_t number =0;

void setup()
{
  uint8_t n = EEPROM.read(0);
  Serial.begin(57600); 
  Serial.print(n);
  number = n;

  // somehow, install "magic" routine here

}

void loop() { }

void magic(void)
{
 ++number;     
 EEPROM.write(0, &number);
}

Answer 1

Yes, it is possible. See the documentation on memory sections, from the avr-libc manual. For example:

// Run this after initializing the stack pointer and zero_reg, but
// before initializing the RAM.
void __attribute__((naked, used, section(".init3"))) magic(void)
{
    // Whatever...
}

Note that this runs after both a warm reset and a cold boot. See Gerben's answer if you want to tell the difference between these two reset conditions.

Note also that, if you just want some data to be preserved through a reset, you can put it in the .noinit section, no need to use the EEPROM.

---

Edit 1: In response to the OP's comment, here is a small program demonstrating the technique. It just quickly blinks the LED three times early in the program initialization, then three more times, more slowly, during setup():

#include <util/delay.h>

// Blink the LED three times, fast, early in the initialization.
void __attribute__((naked, used, section(".init3"))) magic(void)
{
    DDRB |= _BV(PB5);      // pin PB5 = digital 13 as output
    for (int i= 0; i < 6; i++) {
        PINB |= _BV(PB5);  // toggle PB5
        _delay_ms(100);
    }
}

// Blink the LED three times, slowly.
void setup()
{
    pinMode(13, OUTPUT);
    for (int i = 0; i < 6; i++) {
        delay(300);
        digitalWrite(13, !(i & 1));
    }
}

void loop(){}

I tested it on an Uno, and it works.

Note that magic() runs before the Arduino core library has been initialized. At this point, many core function, like delay(), do not work. Any job that is done here should be done low-level, using only direct port access and avr-libc calls.

Edit 2: In the previous version of this answer I forgot the used attribute. It worked with the old Arduino setup I tested with, but not with the newest IDE. Adding the used attribute fixes this.

Answer 2

You can check the MCUSR register to see the cause of the reset. In your case you could use:

if( bit_is_set(MCUSR, EXTRF) )// reset button was pressed
{
    MCUSR = 0;// clear the reset-flag

    // "magic" routine here

}

Answer 3

If you use the latest version (7.0, July 2018) of Optiboot, you can use the MCUSR register to check the reset cause.

You need to use the latest version because previous versions of the bootloader cleared the MCUSR before starting the sketch (as recommended in §15.9.1 of the ATmega328P datasheet). This was changed in version 7.0 (a50f47b).

#include <EEPROM.h>

static uint8_t ch = MCUSR;

void setup() {
  MCUSR = 0;
  uint8_t n = EEPROM.read(0);
  Serial.begin(115200);
  Serial.print(n);
  if ((_BV(PORF) & ch) == 0) // not a power on reset
    magic(n);
}

void loop() { }

void magic(uint8_t &number) {
   EEPROM.put(0, ++number);
}