0

I am a beginner as far as arduino and microcontrollers are concerned. I am using a BMP085 barometric pressure sensor.I have made all the necessary connections to my arduino uno board and double checked them. What I want to do is get readings from the sensor and display them on my arduino serial monitor. The code I am using compiles and uploads without any error but when I open my serial monitor, it is blank. I tried using a humidity/temperature sensor before this and that sensor returns values to the serial monitor. The barometric sensor is new and this was my first time usage.

Here is my sketch. I took it from here. https://www.sparkfun.com/tutorials/253

Any help would be greatly appreciated.

the code

#include <Wire.h>

#define BMP085_ADDRESS 0x77  // I2C address of BMP085

const unsigned char OSS = 0;  // Oversampling Setting

// Calibration values
int ac1;
int ac2; 
int ac3; 
unsigned int ac4;
unsigned int ac5;
unsigned int ac6;
int b1; 
int b2;
int mb;
int mc;
int md;

// b5 is calculated in bmp085GetTemperature(...), this variable is also used in bmp085GetPressure(...)
// so ...Temperature(...) must be called before ...Pressure(...).
long b5; 

short temperature;
long pressure;

// Use these for altitude conversions
const float p0 = 101325;     // Pressure at sea level (Pa)
float altitude;

void setup()
{
  Serial.begin(9600);
  Wire.begin();
  bmp085Calibration();
}

void loop()
{
  temperature = bmp085GetTemperature(bmp085ReadUT());
  pressure = bmp085GetPressure(bmp085ReadUP());
  altitude = (float)44330 * (1 - pow(((float) pressure/p0), 0.190295));

  Serial.print("Temperature: ");
  Serial.print(temperature, DEC);
  Serial.println(" *0.1 deg C");
  Serial.print("Pressure: ");
  Serial.print(pressure, DEC);
  Serial.println(" Pa");
  Serial.print("Altitude: ");
  Serial.print(altitude, 2);
  Serial.println(" m");
  Serial.println();

  delay(1000);
}

// Stores all of the bmp085's calibration values into global variables
// Calibration values are required to calculate temp and pressure
// This function should be called at the beginning of the program
void bmp085Calibration()
{
  ac1 = bmp085ReadInt(0xAA);
  ac2 = bmp085ReadInt(0xAC);
  ac3 = bmp085ReadInt(0xAE);
  ac4 = bmp085ReadInt(0xB0);
  ac5 = bmp085ReadInt(0xB2);
  ac6 = bmp085ReadInt(0xB4);
  b1 = bmp085ReadInt(0xB6);
  b2 = bmp085ReadInt(0xB8);
  mb = bmp085ReadInt(0xBA);
  mc = bmp085ReadInt(0xBC);
  md = bmp085ReadInt(0xBE);
}

// Calculate temperature given ut.
// Value returned will be in units of 0.1 deg C
short bmp085GetTemperature(unsigned int ut)
{
  long x1, x2;

  x1 = (((long)ut - (long)ac6)*(long)ac5) >> 15;
  x2 = ((long)mc << 11)/(x1 + md);
  b5 = x1 + x2;

  return ((b5 + 8)>>4);  
}

// Calculate pressure given up
// calibration values must be known
// b5 is also required so bmp085GetTemperature(...) must be called first.
// Value returned will be pressure in units of Pa.
long bmp085GetPressure(unsigned long up)
{
  long x1, x2, x3, b3, b6, p;
  unsigned long b4, b7;

  b6 = b5 - 4000;
  // Calculate B3
  x1 = (b2 * (b6 * b6)>>12)>>11;
  x2 = (ac2 * b6)>>11;
  x3 = x1 + x2;
  b3 = (((((long)ac1)*4 + x3)<<OSS) + 2)>>2;

  // Calculate B4
  x1 = (ac3 * b6)>>13;
  x2 = (b1 * ((b6 * b6)>>12))>>16;
  x3 = ((x1 + x2) + 2)>>2;
  b4 = (ac4 * (unsigned long)(x3 + 32768))>>15;

  b7 = ((unsigned long)(up - b3) * (50000>>OSS));
  if (b7 < 0x80000000)
    p = (b7<<1)/b4;
  else
    p = (b7/b4)<<1;

  x1 = (p>>8) * (p>>8);
  x1 = (x1 * 3038)>>16;
  x2 = (-7357 * p)>>16;
  p += (x1 + x2 + 3791)>>4;

  return p;
}

// Read 1 byte from the BMP085 at 'address'
char bmp085Read(unsigned char address)
{
  unsigned char data;

  Wire.beginTransmission(BMP085_ADDRESS);
  Wire.write(address);
  Wire.endTransmission();

  Wire.requestFrom(BMP085_ADDRESS, 1);
  while(!Wire.available())
    ;

  return Wire.read();
}

// Read 2 bytes from the BMP085
// First byte will be from 'address'
// Second byte will be from 'address'+1
int bmp085ReadInt(unsigned char address)
{
  unsigned char msb, lsb;

  Wire.beginTransmission(BMP085_ADDRESS);
  Wire.write(address);
  Wire.endTransmission();

  Wire.requestFrom(BMP085_ADDRESS, 2);
  while(Wire.available()<2)
    ;
  msb = Wire.read();
  lsb = Wire.read();

  return (int) msb<<8 | lsb;
}

// Read the uncompensated temperature value
unsigned int bmp085ReadUT()
{
  unsigned int ut;

  // Write 0x2E into Register 0xF4
  // This requests a temperature reading
  Wire.beginTransmission(BMP085_ADDRESS);
  Wire.write(0xF4);
  Wire.write(0x2E);
  Wire.endTransmission();

  // Wait at least 4.5ms
  delay(5);

  // Read two bytes from registers 0xF6 and 0xF7
  ut = bmp085ReadInt(0xF6);
  return ut;
}

// Read the uncompensated pressure value
unsigned long bmp085ReadUP()
{
  unsigned char msb, lsb, xlsb;
  unsigned long up = 0;

  // Write 0x34+(OSS<<6) into register 0xF4
  // Request a pressure reading w/ oversampling setting
  Wire.beginTransmission(BMP085_ADDRESS);
  Wire.write(0xF4);
  Wire.write(0x34 + (OSS<<6));
  Wire.endTransmission();

  // Wait for conversion, delay time dependent on OSS
  delay(2 + (3<<OSS));

  // Read register 0xF6 (MSB), 0xF7 (LSB), and 0xF8 (XLSB)
  Wire.beginTransmission(BMP085_ADDRESS);
  Wire.write(0xF6);
  Wire.endTransmission();
  Wire.requestFrom(BMP085_ADDRESS, 3);

  // Wait for data to become available
  while(Wire.available() < 3)
    ;
  msb = Wire.read();
  lsb = Wire.read();
  xlsb = Wire.read();

  up = (((unsigned long) msb << 16) | ((unsigned long) lsb << 8) | (unsigned long) xlsb) >> (8-OSS);

  return up;
}

wirings: https://imgur.com/a/WJXcM

  • 1
    Show us your code and your wiring. That your code compiles and that you double checked the connection doesn't mean, that there cannot be any wrong coding. – chrisl Apr 15 '18 at 13:44
  • 1
    That web page has several snippets of code, so please do copy/paste the code you are trying into your question. – jose can u c Apr 15 '18 at 13:52
  • The most simple reason: Did you set your serial monitor to use baud rate 9600? Could you also add a Serial.println("SKETCH STARTING"); after the Serial.begin() call to verify that the sketch boots up? – Maximilian Gerhardt Apr 15 '18 at 14:31
  • Could it be that my sensor is faulty? If so, how do I check if my sensor is faulty? I took the entire ino file from the tutorial, and read about what each section of code does. The site did not provide any libraries so all the mathematical calculations are a part of the code. – Hououin Kyoma Apr 15 '18 at 14:32
  • the baud rate is 9600. I just checked it. – Hououin Kyoma Apr 15 '18 at 14:33
1

There are several versions of breakout boards for the BMP085. The device itself is 3v3. Some breakouts provide a regulator so you can supply 5V. Some also perform level-shifting so you can drive the I2C lines at 5V and work correctly with the sensor's 3v3 levels.

It isn't clear which type you have there, but you seem to be powering it from 3v3 on the arduino. A photo of the other side of the sensor board would help.

If the sensor has a regulator, sourcing it from 3v3 will drop it a little (the regulator needs some overhead). This might mean the sensor is running at too low a voltage.

If the board has no regulator, then it's correct to power it from 3v3. However, the I2C lines also need conversion. You will be driving 5V into a 3v3 input, which can damage it. You will also be receiving 3v3 levels from the sensor into the 5V arduino, which will probably work but might not.

Ideally, put level shifters in between. They need to be bidirectional, like these : https://www.adafruit.com/product/757

In some cases you can get away with resistors only, but not easily on the bidirectional I2C bus. SPI is easier as the pins are unidirectional.

| improve this answer | |
  • my sensor 2.bp.blogspot.com/-rYK6t2jDt_0/VxX02W1VNzI/AAAAAAAABCk/… is it possible that i fried the sensor? I connected it to the 3.3v pin on the uno board. I did some reading and found out that the sensor has a 3.3v voltage regulator. I will try to connect it to the 5v pin. – Hououin Kyoma Apr 15 '18 at 17:54
  • It's possible, but it would depend on whether there are also level translators to protect the 3v3 control pins from the 5v arduino pins. – artag Apr 15 '18 at 18:08
  • Adafruit says : V1 of the breakout uses 3.3V power and logic level only V2 of the breakout uses 3.3-5V power and logic level for more flexible usage. – artag Apr 15 '18 at 18:11

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.