2

Is there any way to change the default name (ESP_xxxxx) that the module generates?

  • What do you mean by name? – Dat Ha Oct 7 '16 at 0:39
  • canadiancyborg I edited the question. Now it's understandable! – Sr Julien Oct 7 '16 at 0:49
  • Which firmware are you using? – gre_gor Oct 7 '16 at 11:57
  • Hi gre_gor! I'm not using any firmware, I am using the Arduino IDE. – Sr Julien Oct 9 '16 at 4:28
  • @SrJulien You must be using a firmware on the ESP or it wouldn't work, please determine it before we can really help you efficiently. – Avamander Dec 12 '17 at 16:54
3

This line of code should hopefully do a difference.

wifi_station_set_hostname(myHostname);

For more information :

https://www.reddit.com/r/esp8266/comments/3zl3pi/change_esp8266_network_name/

| improve this answer | |
  • Hi canadiancyborg! I tried to use 'wifi_station_set_hostname', but without success! I appreciate any suggestions! – Sr Julien Oct 9 '16 at 4:33
2

The function is: WiFi.hostname("Name");, make sure you call it before Wifi.begin()

| improve this answer | |
  • This is the actual (modern) answer – Andrew Bullock Feb 26 at 20:04
1

Here you are the code where you can see how you can change network name of your ESP8266 working in AP mode:

#include <ESP8266WiFi.h>
#include <WiFiClient.h>
#include <ESP8266WebServer.h>

IPAddress ip(192,168,1,81);         // choose IP address
IPAddress subnet(255,255,255,0);

ESP8266WebServer server(80);

void handleRoot() {
  String page = "<!DOCTYPE html>\n";

  page += "<html>\n<body>\n<h1>Some heading</h1><br>Generated by ESP8266\n</body>\n</html>";
  server.send(200, "text/html", page);
}

// what to do when accessed through http://ip_address/something_undefined
void handleNotFound(){
  String message = "File not found\n\n";
  message += "URI: ";
  message += server.uri();
  message += "\nMethod: ";
  message += (server.method() == HTTP_GET)?"GET":"POST";
  message += "\nArguments: ";
  message += server.args();
  message += "\n";
  for (uint8_t i=0; i<server.args(); i++){
    message += " " + server.argName(i) + ": " + server.arg(i) + "\n";
  }
  server.send(404, "text/plain", message);
}

void setup(void){
  Serial.begin(74880);                      // so you can see debug messages automatically sent by ESP8266
  WiFi.mode(WIFI_AP);
  WiFi.softAPConfig(ip, ip, subnet);        // declared as: bool softAPConfig (IPAddress local_ip, IPAddress gateway, IPAddress subnet)
  WiFi.softAP("SOME_NAME", "password", 7);  // network name, network password, wifi channel

  IPAddress myIP = WiFi.softAPIP();
  Serial.println();
  Serial.print("AP IP address: ");
  Serial.println(myIP);

  server.on("/", handleRoot);               // what to do when accessed through browser using http://IP_address

  // what to do when accessed through http://ip_address/test
  server.on("/test", [](){
    server.send(200, "text/plain", "This is another page");
  });

  server.onNotFound(handleNotFound);

  server.begin();
  Serial.println("HTTP server started...");
}

void loop(void){
  server.handleClient();
}
| improve this answer | |
0

check the Erase Flash>> Tools >> Arduino IDE before uploading your sketch and select erase previous wifi settings

| improve this answer | |

Not the answer you're looking for? Browse other questions tagged or ask your own question.