Wifi Scanning code for esp32 wroom 32

Question

I am trying to scan wifi in sta_ap mode in my esp32 wroom 32 module but it is not scanning new wifi .Can anybody tell more about how does wifi mode works in this module and what's the problem in my code.Same code is working in esp8266.

CODE:

#include <WiFi.h>

const char *ap_ssid = "ESP32";
const char *ap_password = "";

const char *sta_ssid = "KKACT"; 
const char *sta_password = "kk25990418";
void setup() {
  Serial.begin(115200);
  
  WiFi.mode(WIFI_AP_STA);
  WiFi.disconnect();
  delay(100);
  Serial.print("Configuring access point...");
  WiFi.softAP(ap_ssid, ap_password);

  IPAddress myIP = WiFi.softAPIP();
  Serial.print("AP IP address: ");
  Serial.println(myIP);

  Serial.println();
  Serial.print("Connecting to ");
  Serial.println(sta_ssid);
  WiFi.begin(sta_ssid, sta_password);

  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }

  Serial.println("");
  Serial.println("WiFi connected");
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());
}

void loop() {
   Serial.println("Now scanning wifi continously");
   int n=WiFi.scanNetworks();
   for (int i = 0; i < n; ++i)
  {
      Serial.print(i + 1);
      Serial.print(": ");
      Serial.print(WiFi.SSID(i));
      Serial.print(" (");
      Serial.print(WiFi.RSSI(i));
      Serial.print(")");
    
  }
    delay(2000);
}

Answer 1

This is a issue raised on github about this:

https://github.com/espressif/arduino-esp32/issues/3294

And the issue seems to be that a failed connect prevent the scanning and the solution is:

So what i did was when entering the portal:

WiFi.mode(WIFI_OFF); // otherwise Wifi.Scannetworks() fails

delay(5000);

This seems to stop the processes that prevent the scanning.

After that an immediate scan works without problems.

Answer 2

You are not doing it correctly. In order to perform WiFi scan:

1. It must be in WIFI_STA mode;
2. It has to be disconnect from the AP;
3. After you done with the scanned SSID, BSSID and RSSI, you need to called WiFi.scanDelete() if you are going to do a scan again, otherwise you will get the same previous scanned result.

So in summary, here is the code:

#include <WiFi.h>

void setup() {
  Serial.begin(115200);
  Serial.println();
}

void loop() {
  Serial.println("Scanning WiFi Networks...");
  WiFi.mode(WIFI_STA);
  WiFi.disconnect();
  int n = WiFi.scanNetworks();
  for (int i=0; i<n; i++) {
    Serial.printf("%2d SSID=%-20s RSSI=%d\n", i+1, WiFi.SSID(i).c_str(), WiFi.RSSI(i));
  }
  WiFi.scanDelete();

  delay(10000);
}